Revista do CD-ROM 101/CD-ROM 101.iso/compl/maya5ple/Install_MayaPLE5_English.exe/Maya/Data1.cab/squareSrfToolScript.mel

Text File | 2003-07-17 | 4.9 KB | 167 lines

// Copyright (C) 1997-2002 Alias|Wavefront,
// a division of Silicon Graphics Limited.
//
// The information in this file is provided for the exclusive use of the
// licensees of Alias|Wavefront.  Such users have the right to use, modify,
// and incorporate this code into other products for purposes authorized
// by the Alias|Wavefront license agreement, without fee.
//
// ALIAS|WAVEFRONT DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
// INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
// EVENT SHALL ALIAS|WAVEFRONT BE LIABLE FOR ANY SPECIAL, INDIRECT OR
// CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
// DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
// TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
// PERFORMANCE OF THIS SOFTWARE.
//
//
// Alias|Wavefront Script File
// MODIFY THIS AT YOUR OWN RISK
//
// Creation Date:  14 January 1999
// Author:         sw
//
//
//  Procedure Name:
//      squareSrfToolScript
//
//  Description:
//    create wrapper around the squareSrf command
//
//  Input Arguments:
//        0 ==> do the command.
//        1 ==> show the action option box
//        2 ==> return the command
//        3 ==> show tool option box
//        4 ==> enter the tool
//
//  Return Value:
//      None.
//

global proc squareSrfValues ( string $toolName )
{
    performSquareSrf 3 $toolName;
    scriptCtxCommonValues( $toolName );
}

global proc squareSrfProperties()
{
    scriptCtxCommonProperties;
}

global proc squareSrf4curves( int $ncurves, string $goToTool )
{
    scriptCtx -e -ssc $ncurves $goToTool;
    if( 4 == $ncurves ) {
        scriptCtx -e
          -setNoSelectionPrompt ("Select 4 curve(s), isoparm(s) " +
                                 "or trim edges forming a " +
                                 "closed region).")
          -setSelectionPrompt ("Select 4 curves, isoparms or trim " +
                               "edges forming a closed region; " +
                               "press ENTER to compute square surface.")
          -setSelectionCount 4
          $goToTool;
    }
    else if( 3 == $ncurves ) {
        scriptCtx -e
          -setNoSelectionPrompt ("Select 3 curve(s), isoparm(s) " +
                                 "or trim edges forming a " +
                                 "closed region).")
          -setSelectionPrompt ("Select 3 curves, isoparms or trim " +
                               "edges forming a closed region; " +
                               "press ENTER to compute square surface.")
          -setSelectionCount 3
          $goToTool;
    }
    else {
        scriptCtx -e
          -setNoSelectionPrompt ("Select 3 or 4 curve(s), isoparm(s) " +
                                 "or trim edges forming a " +
                                 "closed region).")
          -setSelectionPrompt ("Select 3 or 4 curves, isoparms or trim " +
                               "edges forming a closed region; " +
                               "press ENTER to compute square surface.")
          -setSelectionCount 0
          $goToTool;
    }
}

global proc squareSrfToolSetup( int $forceFactorySettings, string $goToTool )
{
    if( $forceFactorySettings || !`optionVar -ex closeSurfaceEuc` ) {
        optionVar -iv squareSurfaceEuc 0;
    }
    if( $forceFactorySettings || !`optionVar -ex squareSurfaceLac` ) {
        optionVar -iv squareSurfaceLac 1;
    }
    if( "" != $goToTool ) {
        scriptCtx -e -euc `optionVar -q squareSurfaceEuc` $goToTool;
        scriptCtx -e -lac `optionVar -q squareSurfaceLac` $goToTool;
        squareSrf4curves `optionVar -q squareSrfAutoEdgeCount` $goToTool;
    }
}

global proc squareSrfAutoComplete( int $val, string $goToTool )
{
    scriptCtx -e -lac $val $goToTool;
    squareSrf4curves `optionVar -q squareSrfAutoEdgeCount` $goToTool;
}

proc createSquareSrfContext( string $tool )
{
    if( ! `scriptCtx -exists $tool` ) {
        squareSrfToolSetup( 0, "" );
        scriptCtx -i1 "squareSrf.xpm"
          -title "Square Surface Tool"
          -bcn "squareSrf"

          -exitUponCompletion `optionVar -q squareSurfaceEuc`
          -totalSelectionSets 1
          -expandSelectionList true
          -fcs ("squareSrfToolScript 0")

          -setNoSelectionPrompt ("Select 3 or 4 curve(s), isoparm(s) " +
                                 "or trim edges forming a " +
                                 "closed region).")
          -setSelectionPrompt ("Select 3 or 4 curves, isoparms or trim " +
                               "edges forming a closed region; " +
                               "press ENTER to compute square surface.")

          -setAutoToggleSelection true
          -setAutoComplete `optionVar -q squareSurfaceLac`
          -showManipulators true

          -setSelectionCount 4
          -nurbsCurve true
          -isoparm true
          -curveOnSurface true
          -surfaceEdge true
          -polymeshEdge true
        $tool;
    }
}

global proc string squareSrfToolScript( int $setToTool )
//
//    Description :
//        0 ==> do the command.
//        1 ==> show the action option box
//        2 ==> return the command
//        3 ==> show tool/action option box
//        4 ==> enter the tool/do the command
{
    string $tool = "";
    if( $setToTool > 2 ) {
        if( !`optionVar -q modelWithToolSquareSrf` ) {
            $setToTool = 4 - $setToTool;
        }
        else {
            $tool = "squareSrfContext";
            createSquareSrfContext $tool;
        }
    }
    return scriptToolScript( "performSquareSrf", $setToTool, $tool );
}